//////////////////////////////////////
////////// Incentives paper code 
////// Author: Charlotte Booth
///// Date: 05.12.2023
/// charlotte.booth@ucl.ac.uk

/// Load data:
cls
clear
use "file_path"


/// Data processing:
*create variable for response type
gen response_type=0
replace response_type=1 if CW3WEB==1
replace response_type=2 if CW3TEL==1
lab def response_type 0 "no response" 1 "online" 2 "telephone"
lab values response_type response_type 
tab response_type

misstable sum (Sex White Country Poverty parent_degree mcs7_nonresponse response_type)

*create global for analysis sample
global if "if Sex!=. & White!=. & Country!=. & parent_degree!=."

*recode telephone productive to 0 
recode CW3PROD (1=0) if response_type==2

*check response rate by incentive group
tab CW3PROD $if
tab MCSIncentive $if
tab CW3PROD MCSIncentive $if, col


/// Descriptive statistics (Table 1):
foreach var of varlist Sex White England Wales Scotland NI Poverty parent_degree mcs7_nonresponse CW3PROD {
	
	ttest `var' $if, by(MCSIncentive)
	tab `var' MCSIncentive $if
	
}


/// Incentive on response rate (Table 2):
*create global for list of covariates
global cov "i.Sex i.White i.Country i.Poverty i.parent_degree i.mcs7_nonresponse"


*Unadjusted model 
reg CW3PROD i.MCSIncentive $if, robust 
outreg2 using Response_rate_151023, excel ctitle(Unadj) sideway noparen dec(2) label

*Adjusted model
reg CW3PROD i.MCSIncentive $cov $if, robust 
outreg2 using Response_rate_151023, excel ctitle(Adj) sideway noparen dec(2) label

*Interactions
reg CW3PROD i.MCSIncentive $cov i.MCSIncentive#i.Sex $if, robust 
outreg2 using Response_rate_151023, excel ctitle(#Sex) sideway noparen dec(2) label

reg CW3PROD i.MCSIncentive $cov i.MCSIncentive#i.White $if, robust 
outreg2 using Response_rate_151023, excel ctitle(#Ethnic) sideway noparen dec(2) label

reg CW3PROD i.MCSIncentive $cov i.MCSIncentive#i.Country $if, robust 
outreg2 using Response_rate_151023, excel ctitle(#Country) sideway noparen dec(2) label

reg CW3PROD i.MCSIncentive $cov i.MCSIncentive#i.Poverty $if, robust 
outreg2 using Response_rate_151023, excel ctitle(#Poverty) sideway noparen dec(2) label

reg CW3PROD i.MCSIncentive $cov i.MCSIncentive#i.parent_degree $if, robust 
outreg2 using Response_rate_151023, excel ctitle(#Paredu) sideway noparen dec(2) label

reg CW3PROD i.MCSIncentive $cov i.MCSIncentive#i.mcs7_nonresponse $if, robust 
outreg2 using Response_rate_151023, excel ctitle(#Nonresp) sideway noparen dec(2) label

margins i.MCSIncentive#i.mcs7_nonresponse


*Sensitivity analyses (without other covariates)
reg CW3PROD i.MCSIncentive##i.Sex $if
reg CW3PROD i.MCSIncentive##i.White $if
reg CW3PROD i.MCSIncentive##i.Country $if
reg CW3PROD i.MCSIncentive##i.Poverty $if
reg CW3PROD i.MCSIncentive##i.parent_degree $if
reg CW3PROD i.MCSIncentive##i.mcs7_nonresponse $if

margins i.MCSIncentive#i.mcs7_nonresponse



/// Incentive on data quality (Table 3):

*Data processing
gen cw3_survey_mins = cw3_survey_time / 60
gen cw3_survey_mins_cont = cw3_survey_mins
replace cw3_survey_mins_cont = . if cw3_survey_mins_cont < 1
replace cw3_survey_mins_cont = . if cw3_survey_mins_cont > 61

gen skip = 1 if cw3_open_length == 0
replace skip = 0 if inrange(cw3_open_length, 4, 3440)
tab skip


*Global for analysis sample for data quality 
global one "if Sex!=. & White!=. & Country!=. & parent_degree!=. & mcs7_nonresponse!=. & response_type!=2"
global two "if Sex!=. & White!=. & Country!=. & parent_degree!=. & mcs7_nonresponse!=. & response_type!=2 & CW3_OUTCOME==1"

tab CW3_OUTCOME $one
tab straightline_soc $two
sum cw3_survey_mins_cont $two

*Data quality analyses
svyset CW3_SPTN00 [pweight=CW3_COMBWT], strata(CW3_PTTYPE2) fpc(CW3_NH2)

*1) Survey break-off
svy: reg CW3_OUTCOME i.MCSIncentive $cov $one
outreg2 using Data_quality_061023, excel ctitle(Drop_off) sideway noparen dec(2)label 

*2) Item non-response
svy: reg non_resp i.MCSIncentive $cov $two
outreg2 using Data_quality_061023, excel ctitle(Non_resp) sideway noparen dec(2)label 

*3) Straightlining 
svy: reg straightline_soc i.MCSIncentive $cov $two
outreg2 using Data_quality_061023, excel ctitle(Straight) sideway noparen dec(2)label 

*4) Skipping free text
svy: reg skip i.MCSIncentive $cov $two
outreg2 using Data_quality_061023, excel ctitle(Incompl) sideway noparen dec(2)label 

*5) Speeding
svy: reg cw3_survey_mins_cont i.MCSIncentive $cov $two
outreg2 using Data_quality_061023, excel ctitle(Time) sideway noparen dec(2)label 



/// Incentive on later survey participation (Table 4):

tab MCSIncentive CW3PROD $if, row

tab MCSIncentive AUTPROD $if, row

ttest AUTUMNPROD $if, by(MCSIncentive)